From 8710105f65154d19f7c65be10dd95b0e4ccab63b Mon Sep 17 00:00:00 2001
From: Ethel Morgan <eth@ethulhu.co.uk>
Date: Mon, 29 Jun 2020 23:18:00 +0100
Subject: refactor eth.services.catbus-{networkpresence,wakeonlan}

---
 nixos/modules/services/catbus-wakeonlan.nix | 69 +++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 nixos/modules/services/catbus-wakeonlan.nix

(limited to 'nixos/modules/services/catbus-wakeonlan.nix')

diff --git a/nixos/modules/services/catbus-wakeonlan.nix b/nixos/modules/services/catbus-wakeonlan.nix
new file mode 100644
index 0000000..0cf7edb
--- /dev/null
+++ b/nixos/modules/services/catbus-wakeonlan.nix
@@ -0,0 +1,69 @@
+{ config, lib, pkgs, ... }:
+with lib;
+
+let
+
+  cfg = config.eth.services.catbus-wakeonlan;
+
+  configJSON = pkgs.writeText "config.json" (builtins.toJSON {
+    mqttBroker = cfg.mqttBroker;
+    devices = cfg.devices;
+  });
+
+in {
+
+  options.eth.services.catbus-wakeonlan = {
+
+    enable = mkEnableOption "Whether to enable the Catbus Wake-On-LAN actuator";
+
+    mqttBroker = mkOption {
+      type = types.str;
+      description = "URL of the MQTT broker.";
+      example = "tcp://broker.local:1883";
+    };
+
+    devices = mkOption {
+      type = types.attrsOf (types.submodule {
+        options = {
+          mac = mkOption {
+            type = types.str;
+            description = "The device's MAC address";
+            example = "aa:bb:cc:dd:ee:ff";
+          };
+          topic = mkOption {
+            type = types.str;
+            description = "MQTT topic for controlling the device";
+            example = "home/house/speakers/power";
+          };
+        };
+      });
+      example = { TV = { mac = "aa:bb:cc:dd:ee:ff"; topic = "home/living-room/tv/power"; }; };
+      description = "A set of devices and their MACs & controller topics.";
+    };
+  };
+
+
+  config = mkIf cfg.enable {
+    systemd.services.catbus-wakeonlan-actuator = {
+      enable = true;
+      description = "Power devices on using Wake-On-LAN via Catbus";
+      wants = [ "network.target" ];
+      after = [ "network.target" ];
+      wantedBy = [ "multi-user.target" ];
+      serviceConfig = {
+        DynamicUser = true;
+
+        ExecStart = "${pkgs.eth.catbus-wakeonlan}/bin/catbus-actuator-wakeonlan --config-path ${configJSON}";
+
+        NoNewPrivileges = true;
+        ProtectKernelTunables = true;
+        ProtectControlGroups = true;
+        ProtectKernelModules = true;
+        RestrictAddressFamilies = "AF_INET AF_INET6";
+        RestrictNamespaces = true;
+      };
+    };
+  };
+
+}
+
-- 
cgit v1.2.3